|
|
|
| Братцы помогите разобраться новичку, делаю бегущую строку (ActionScript) нашел отличный скриптик, но никак не могу поменять шрифт Times и увеличить размер шрифта, помогите кто может.
messageURL = "text.txt";
message_num = 1;
size_mc = 100;
xscale = 490;
speedLine = 1;
xpos = 0;
ypos = 161;
txt_border = false;
txt_color = 0xFFFFFF; // 0x[ваш Цвет]
//Cоздаём пустой МувиКлип
var fon:MovieClip = this.createEmptyMovieClip("fon_mc", 1);
fon._xscale = size_mc;
fon._yscale = size_mc;
//Создаем Мувики для аттача стрелок на сцену
var mc:MovieClip = fon.attachMovie("str", "str", 998, {_alpha:100, _x:xpos+xscale-15, _y:ypos+35});
var mc2:MovieClip = fon.attachMovie("str", "str2", 999, {_alpha:100, _x:xpos+xscale-25, _y:ypos+35});
mc2._xscale = -100;//Переворачиваем кнопку
//Кнопка Следующее сообщение
mc.btn.onPress = next_message;
function next_message():Void {
counter++;
success();
}
//Кнопка Предыдущее сообщение
mc2.btn.onPress = prev_message;
function prev_message():Void {
counter--;
success();
}
//Аттачим мувик выступающий в роли фона
var mc_fon:MovieClip = fon.attachMovie("fon", "fon", 1, {_alpha:100, _x:xpos, _y:ypos+10});
mc_fon._xscale = xscale;
var container:MovieClip = fon.createEmptyMovieClip("text_mc", 2);
//Создаём текстовое поле в которое будет грузиться из нашего txt информация
var pole_txt:TextField = container.createTextField("pole_txt", xpos, xscale+xpos, ypos+10, 500, 25);
pole_txt.autoSize = true;//автоматическое выравнивание текстого поля
pole_txt.html = true;//наше текстовое поле понимает html тэги
pole_txt.selectable = false;//выделение текста
pole_txt.border = txt_border;//границы поля
pole_txt.textColor = txt_color;//цвет текста
//Создаём мувик-маску для скрытия уходящих за пределы маски букв
var maska:MovieClip = fon.createEmptyMovieClip("maska_mc", 3);
//Рисуем в мувиКлипе прямоугольник
maska.beginFill(0xFF0000);
maska.moveTo(10,10);
maska.lineTo(xscale,10);
maska.lineTo(xscale,55);
maska.lineTo(10,55);
maska.lineTo(10,10);
maska.endFill();
maska._x = xpos;
maska._y = ypos;
//Сделали мувик маской и применили к text_mc
fon_mc.setMask(maska);
//Загружаем текст из text.txt
var myVars:LoadVars = new LoadVars();
//Если загрузка закончена
myVars.onLoad = success;
function success():Void {
if (typeof (myVars["message"+counter]) != "string") {
counter = message_num;
}
pole_txt.text = myVars["message"+counter];
//Получили длину текстового поля
var_num = "-"+pole_txt._width;
go();
}
myVars.load(messageURL);
//Функция запускающая onEnterFrame и соответственно движение нашей бегущей строчки.
function go():Void {
container.onEnterFrame = function() {
if (pole_txt._x>var_num) {
pole_txt._x -= speedLine;
} else {
pole_txt._x = xscale+xpos;
counter++;
success();
}
};
}
|
| |
|
|
|
|
|
|
|
для: Tamplier
(09.08.2010 в 11:43)
| | перед
pole_txt.autoSize = true;//автоматическое выравнивание текстого поля
вставить
var format:TextFormat = new TextFormat();
format.font = "Verdana";
format.size = 20;
format.bold = true;
format.color = 0xffffff;
pole_txt.setTextFormat(format)
|
| |
|
|
|
|
|
|
|
для: elenaki
(09.08.2010 в 12:34)
| | Неа не работает, я так тоже пробовал, но почему-то не форматирует....!?!
Может в коде есть что-то что мешает отформатировать текст??? | |
|
|
|
|
|
|
|
для: Tamplier
(09.08.2010 в 14:51)
| | задавать форматирование стоит после внесения данных
-->
pole_txt.text = myVars["message"+counter]; | |
|
|
|
|
|
|
|
для: AlexSol
(09.08.2010 в 15:14)
| | Спасибо!!! Так действительно работает, я ваш должник!!! | |
|
|
|